BDE Analyse
Laten we beginnen met een kleine GUI om alle mogelijke BDE aliases strings op te halen die op een machine aanwezig zijn, en voor een gekozen alias alle tabellen op te sommen die daarbinnen te vinden zijn. Hier hebben we twee TComboBox componenten voor nodig, genaamd cbDatabases en cbTables. Het vullen van de cbDatabases met de aanwezige alias strings gaat met behulp van een TSession component als volgt, bijvoorbeeld in de FormCreate:

  procedure TFormSDE.FormCreate(Sender: TObject);
  begin
    Session1.GetDatabaseNames(cbDatabases.Items);
  end;

  procedure TFormSDE.cbDatabasesChange(Sender: TObject);
  begin
    Database1.Close;
    Database1.DatabaseName := cbDatabases.Items[cbDatabases.ItemIndex];
    Database1.GetTableNames(cbTables.Items, cbSystemTables.Checked);
  end;

  procedure TFormSDE.cbTablesChange(Sender: TObject);
  begin
    Table1.CLose;
    Table1.DatabaseName := Database1.DatabaseName;
    Table1.TableName := cbTables.Items[cbTables.ItemIndex];
  end;

SQL CREATE TABLE
De basis syntax van het SQL CREATE TABLE command is kort gezegd als volgt:

  CREATE TABLE <tablename> ( <fieldname> <fieldtype> [size]  [[NOT] NULL] )

  function Table2SQL(const Table: TTable): String;
  var
    i: Integer;
    Str: String;
  begin
    Table.Open;
    Table.FieldDefs.Update;
    Table.IndexDefs.Update;
    try
      Str := 'CREATE TABLE ' +
        ChangeFileExt(Table.TableName, '') + '(';
      for i:=0 to Table.Fields.Count-1 do
      begin
        Str := Str + '"' + Table.Fields[i].DisplayName + '" ';

        // fieldtype

        if Table.FieldDefs[i].Required then Str := Str + ' NOT';
        Str := Str + ' NULL';
        if (i < Table.Fields.Count-1) then Str := Str + ', ';
      end;
      Str := Str + ')';

      Result := Str;
    finally
      Table.Close;
    end
  end;

Field Mapping
Voor SQL Server en Blackfish SQL heb ik de volgende field mappings gevonden, waarbij ik aan de BDE / SQL Links kant uitga van de waarde van de Table.FieldDefs[i].FieldClass en aan de DBMS kant het corresponderende type heb gekozen:

BDE / SQL Links	SQL Server	Blackfish SQL
TStringField	[N]VARCHAR(size)	[N]VARCHAR(size)
TIntegerField	INTEGER	INTEGER
TSmallIntField	SMALLINT	SMALLINT
TFloatField	FLOAT	DOUBLE
TDateTimeField	DATETIME	TIMESTAMP
TDateField	DATE	DATE
TTimeField	TIME	TIME
TCurrencyField	DECIMAL	DECIMAL
TBooleanField	BIT	BOOLEAN
TMemoField	[N]TEXT	[N]VARCHAR
TGraphicField	IMAGE	VARBINARY
TBlobField	IMAGE	VARBINARY

      if Table.FieldDefs[i].FieldClass = TStringField then
        Str := Str + ' VARCHAR(' + IntToStr(Table.FieldDefs[i].Size) + ')'
      else
      if Table.FieldDefs[i].FieldClass = TSmallIntField then
        Str := Str + ' SMALLINT '
      else
      if Table.FieldDefs[i].FieldClass = TIntegerField then
        Str := Str + ' INTEGER '
      else
      if Table.FieldDefs[i].FieldClass = TDateTimeField then
        Str := Str + ' DATETIME ' // TIMESTAMP '
      else
      if Table.FieldDefs[i].FieldClass = TMemoField then
        Str := Str + ' TEXT ' // OBJECT '
      else
      if Table.FieldDefs[i].FieldClass = TGraphicField then
        Str := Str + ' IMAGE ' // OBJECT  '
      else
      if Table.FieldDefs[i].FieldClass = TBLobField then
        Str := Str + ' IMAGE ' // OBJECT '
      else
      if Table.FieldDefs[i].FieldClass = TFloatField then
        Str := Str + ' FLOAT ' // DOUBLE '
      else
        raise Exception.Create('Unsupported field type ' +
          Table.FieldDefs[i].FieldClass.ClassName);

CREATE TABLE country("Name"  VARCHAR(24) NULL, "Capital"  VARCHAR(24) NULL,
  "Continent"  VARCHAR(24) NULL, "Area"  FLOAT  NULL, "Population"  FLOAT  NULL)

Copy Copy
En dan nu de laatste stap: het overpompen van de data uit de BDE / SQL Links tabel naar de SQL DBMS. Dat kan door gebruik te maken van een aantal DBX4 componenten die de BDE records eerst inlezen in een TClientDataSet, en daarna alles naar het SQL DBMS sturen. Allereerst is daar de dbExpress SQLConnection component die een verbinding met het SQL DBMS moet maken – hiertoe moet je de juiste connection properties opgeven. Dan is er een SQLDataSet die via zijn SQLConnection property aan de SQLConnection component verbonden is, en een SELECT * FROM uitvoert op de betreffende (nog lege) tabel die we eerder met het CREATE TABLE command hebben aangemaakt. Een TDataSetProvider verbonden met de SQLDataSet en een TClientDataSet verbonden met de DataSetProvider maken het plaatje compleet. Bij over overkopieren hoeven we nu alleen nog maar door de BDE / SQL Links TTable heen te lopen, en per record een Append te doen in de ClientDataSet (met Append komt ieder volgend record achter het vorige, zodat we dezelfde volgorde aanhouden als in de BDE table). Vervolgens kunnen we van ieder veld de waarde kopiëren door de Fields[i].Value te gebruiken. Wat nog iets beter is (ook voor memo velden) is om Assign te gebruiken om de waarde van de BDE velden toe te kennen aan die van de DBX4 velden. Hierbij ga ik wel uit van het feit dat beide tabellen de velden in exact dezelfde volgorde hebben staan (zodat we niet via FieldByName hoeven te zoeken, maar kunnen volstaan met de mapping van veld i uit de BDE tabel naar veld i van de SQL DBMS tabel). Omdat de SQLDataSet met een SELECT * FROM werd gestart, zal bij de aanroep van ApplyUpdates van de ClientDataSet automatisch een bijbehorende SQL INSERT worden gegenereerd.

  procedure TFormSDE.btnCopyClick(Sender: TObject);
  var
    i: Integer;
  begin
    ClientDataSet1.Close;
    Table1.Open;
    SQlDataSet1.CommandText := 'SELECT * FROM ' +
      ChangeFileEXt(Table1.TableName,'');
    ClientDataSet1.Active := True;
    while not Table1.Eof do
    begin
      ClientDataSet1.Append;
      for i:=0 to Table1.Fields.Count-1 do
        ClientDataSet1.Fields[i].Assign(Table1.Fields[i]);
      ClientDataSet1.Post;
      ClientDataSet1.ApplyUpdates(0);
      Table1.Next;
    end;
    Table1.Close;
  end;

Conclusie
In dit artikel heb ik laten zien hoe we vanuit een BDE / SQL Links een SQL CREATE TABLE command kunnen produceren, en dit kunnen gebruiken om een nieuwe vergelijkbare tabel in een SQL DBMS te maken, gevolgd door het kopiëren van de data uit de BDE tabel naar de corresponderende tabel in het SQL DBMS. Hiermee kan op eenvoudige wijze BDE data naar een SQL DBMS gemigreerd worden. Wie nog vragen of opmerkingen heeft kan me altijd per e-mail bereiken of een bezoek brengen aan mijn nieuwe trainingsruimte in Helmond Brandevoort.